🚀 go-pugleaf

;
; Skrypt do połączenia z Internet via TPSA
;

proc main

   ; Jezeli Twoj Internet Provider ma inny LOGIN,
   ; to zmien ponizsze ustawienia.
   ; Skorzystaj wpierw z logowania recznego
   ; i zanotuj komunikaty.

   string sLogin = "Username: "
   string sPassw = "Password: "

   ; deklaracja zmiennej ilosci prob polaczenia

   integer nTries = 10

   ; deklaracja zmiennych dla czasow oczekiwania

   integer nLoginTimeout = 3
   integer nPassTimeout = 3

   ; proba dokonania polaczenia co najwyzej 'nTries' razy

   while 0 < nTries do

      delay 2
      waitfor sLogin then DoLogin
        until nLoginTimeout

TryAgain:
      transmit "^M"
      nTries = nTries - 1

   endwhile

   goto BailOut

DoLogin:
   ; wprowadzenie identyfikatora uzytkownika (login name)
   ; zalezne od Internet Provider'a i uzytkownika
   ; w TPSA zawsze jest 'ppp'
   ; ^M oznacza oczywiscie nacisniecie ENTER'a

   transmit "ppp"
   transmit "^M"

   ; oczekiwanie na zapytanie (prompt) o haslo (password)

   waitfor sPassw until nPassTimeout
   if FALSE == $SUCCESS then
      goto TryAgain
   endif

   ; wprowadzenie hasla (password)
   ; zalezne od Internet Provider'a i uzytkownika
   ; dla TPSA jest takie samo, jak identyfikator

   transmit "ppp"
   transmit "^M"

   ; Czasem zachodzi potrzeba wprowadzenia jeszcze jednej
   ; petli,  o ile logowanie jest trzystopniowe.
   ; To juz chyba potraficie zrobic sami.

   goto Done

BailOut:
   ; Brak prawidlowej odpowiedzi. Zatrzymanie skryptu
   ; i umozliwienie uzytkownikowi obslugi recznej.

   set screen keyboard on
   halt

Done:

endproc

-- 
Jacek Jędrzejowski alias Quickkwik
<jacek@dom.zabrze.pl>