🚀 go-pugleaf

On Mon, 06 Dec 2010 21:10:18 +0100, Maciej Misiak wrote:

> 3. znaczenia pętli for ($i=309;$i>=31;$i--) nie rozumiem, więc pozostaje 
> tylko przypuszczać: czytanie pliku "$dir/maillog.$i" wyciągnij przed tą 
> pętlę. Po co 309-31 razy go wczytujesz? I x2, bo dla dwóch skrzynek?

Ej, skup się. On nie czyta tego samego pliku, tylko pliki o nazwach
maillog.309, maillog.308, i tak dalej aż do maillog.31.
Dlaczego akurat takie nazwy plików? A to już jego słodka tajemnica. Jeśli
nie chodzi o to, żeby z premedytacją pominąć nazwy spoza tego zakresu, to
prościej byłoby pewnie zrobić tak:

for my $nazwa (glob "$dir/mailbox.*") {
  open UCHWYT, $nazwa;

itd. 

Oczywiście ten program jest napisany tak koszmarnie, że podobnie jak Kacper
miałem problem ze zrozumieniem, co on właściwie robi, ale zgaduję, że chodzi
o wyszukanie w logach wszystkich linii, które odnoszą się do poczty od/do
danego użytkownika - czyli najpierw znajdujemy linie z danym adresem e-mail,
a potem wszystkie linie z takim samym queue id, jak te znalezione wcześniej.
Co oznacza, że można to zapisać znacznie zgrabniej, na dwa sposoby, z czego
przedstawiam tu tylko jeden, który wymaga dwukrotnego przeczytania logów,
ale jest oszczędniejszy z punktu widzenia pamięci niż drugi, który w
pierwszej kolejności wczytuje logi *w całości* do pamięci.

To byłoby jakoś tak:

#!/usr/bin/perl
use warnings;
use strict;

my $logi = '/var/log/mail.*';
my $output = '/var/log/wynik';
my @skrzynki = ('biuro@xxx.pl', 'marketing@xxx.pl');

my $regexp = join '|',  map "\Q$_\E", @skrzynki;
my %qid;

# pierwszy przebieg
for my $nazwa (glob $logi) {
  # jak się nie da otworzyć, pomijamy plik cichcem
  open UCHWYT, '<', $nazwa or next;
  while(<UCHWYT>) {
    if($_ =~ /(?:from|to)=<($regexp)>/o) {
      # znaleziono jeden z szukanych adresów
      my $adres = $1;
      # ustalamy queue-id
      if(m/:\s([0-9A-F]{10}):\s/) {
        # mapujemy queue-id na adres
        $qid{$1} = $adres;
      }
    }
  }
  close UCHWYT;
}

# otwieramy sobie pliki wyjściowe
my %uchwyt;
for my $adres (@skrzynki) {
  # ale jak się nie da zapisywać, to pora umierać
  open $uchwyt{$adres}, '>', "$output/$adres" or die;
}

# drugi przebieg
for my $nazwa (glob $logi) {
  open UCHWYT, $nazwa or next;
  while(<UCHWYT>) {
    if(m/:\s([0-9A-F]{10}):\s/ && $qid{$1}) {
      # linia zawiera jeden z szukanych queue-id
      # wypiszemy ją do właściwego pliku
      print {$uchwyt{$qid{$1}}} $_;
    }
  }
  close UCHWYT;
}

# zamykamy pliki wyjściowe
for my $adres (@skrzynki) {
  close $uchwyt{$adres};
}

exit 0;

(tak, mam pilną robotę, zupełnie niezwiązaną z Perlem, a bo co?)
-- 
Szymon Sokół (SS316-RIPE) -- Network Manager                                 B
Computer Center, AGH - University of Science and Technology, Cracow, Poland  O
http://home.agh.edu.pl/szymon/ PGP key id: RSA: 0x2ABE016B, DSS: 0xF9289982  F
Free speech includes the right not to listen, if not interested -- Heinlein  H