🚀 go-pugleaf

On Thu, 14 Apr 2011 22:24:08 +0200, Maciej Misiak wrote:

> W dniu 2011-04-14 08:47, Antiloop pisze:
> 
>> Zastanawiający jest fakt iż nie korzystasz z metody fetchrow_array(),
>> gdyż ja zawsze korzystałem własnie z niej.
>> Jakie są plusy z korzystania z fetchall_arrayref()?
> 
> Z reguły w przypadkach małych ilości danych żadne, dopiero jak się robią 
> duże ilości rekordów albo dowolne ilości, ale w wielu wątkach to 
> referencje potrafią zaoszczędzić wiele pamięci.

Podstawową zaletą grupy funkcji fetchall_hashref, fetchall_arrayref,
selectall_hashref, selectall_arrayref jest to, że zwracają jednym
wywołaniem komplet danych generowanych przez dane zapytanie SQL. Jest to
zarazem podstawowa wada. Wada, bo zjada sporo pamięci, zaleta, bo można
hurtem na całości danych operować, zamiast rekord po rekordzie.
Przykładowo, w celu wypisania imion wszystkich Nowaków i Kowalskich (osobno
jednych, osobno drugich) z tabeli 'obywatele' można zrobić:

         my $sth = $dbh->prepare("SELECT imie, nazwisko FROM obywatele WHERE nazwisko=?");
         for my $nazwisko ('Nowak', 'Kowalski') {
           $sth->execute( $nazwisko );
           while ( my @row = $sth->fetchrow_array ) {
             print "@row\n";
           }
         }

albo:

         my $sth = $dbh->prepare("SELECT imie, nazwisko FROM obywatele WHERE nazwisko=?");
         for my $nazwisko ('Nowak', 'Kowalski') {
           $sth->execute( $nazwisko );
           while ( my $row = $sth->fetchrow_arrayref ) {
             print "@$row\n";
           }
         }

ale można też:

         my $sth = $dbh->prepare("SELECT imie, nazwisko FROM obywatele WHERE nazwisko=?");
         for my $nazwisko ('Nowak', 'Kowalski') {
           $sth->execute( $nazwisko );
           my $all_rows = $sth->fetchall_arrayref;
           for my $row ( @$all_rows ) {
             print "@$row\n";
           }
         }

albo wręcz:

         for my $nazwisko ('Nowak', 'Kowalski') {
           my $all_rows = $dbh->selectall_arrayref("SELECT imie, nazwisko FROM obywatele WHERE nazwisko=?", {}, $nazwisko);
           for my $row ( @$all_rows ) {
             print "@$row\n";
           }
         }

-- 
Szymon Sokół (SS316-RIPE) -- Network Manager                                 B
Computer Center, AGH - University of Science and Technology, Cracow, Poland  O
http://home.agh.edu.pl/szymon/ PGP key id: RSA: 0x2ABE016B, DSS: 0xF9289982  F
Free speech includes the right not to listen, if not interested -- Heinlein  H