🚀 go-pugleaf

W dniu 2020-03-14 o 12:02, Phantom pisze:
> Witam
> Mam podformularz (dane ciągłe) z poziomym paskiem przewijania i mnóstwem kolumn m.in z kwotami dla poszczególnych miesięcy w roku (czyli od stycznia do grudnia). Wiersze to poszczególne lata rozliczeniowe (2018, 2019, 2020). W podformularzu widzę tylko kolumny z miesiącami od stycznia do czerwca. Reszta ukryta i dostępna tylko po przewinięciu paskiem.
> Chciałbym, żeby pasek przewinął automatycznie (jeżeli jest np.: marzec) i pokazał dane od marca i dalej (ukryty z lewej strony styczeń, luty).
> Nazwy pól podformularza to odpowiednio:
> styczeń - m1rozl;
> luty - m2rozl;
> .
> .
> grudzień - m12rozl
> 

Spróbuj coś takiego:
Nazwy etykiet kolumn są następujące:

  styczeń - lblm1rozl;
  luty - lblm2rozl;
  .
  .
  grudzień - lblm12rozl

'___________________________________________
Private Sub Form_Open(Cancel As Integer)

Dim iMonth As Integer
Dim lMoveLeft As Long
Dim i As Long

   ' pobierz numer miesiąca
   iMonth = CStr(Month(Now()))

   ' ustaw najpierw fokus na pierwszym widocznym
   Me.Controls("m" & iMonth & "rozl").SetFocus

   ' wylicz przesunięcie dla widocznych formantów
   lMoveLeft = Me.Controls("m" & iMonth & "rozl").Left _
             - Me.Controls("m" & "1" & "rozl").Left

   For i = 1 To iMonth - 1
     ' ukryj formanty młodsze
     Me.Controls("m" & CStr(i) & "rozl").Visible = False
     ' i etykiety ich kolumn
     Me.Controls("lblm" & CStr(i) & "rozl").Visible = False

   Next

   ' widoczne kolumny
   For i = iMonth To 12
     ' przesuń kolumny w lewo
     Me.Controls("m" & CStr(i) & "rozl").Left = _
                 Me.Controls("m" & CStr(i) & "rozl").Left - lMoveLeft
     ' i etykiety powiązane w lewo
     Me.Controls("lblm" & CStr(i) & "rozl").Left = _
                  Me.Controls("lblm" & CStr(i) & "rozl").Left - lMoveLeft

   Next

End Sub

Przesunięcie pozostałych elementów oraz rozmiar formularza
musisz oprogramować sam.

-- 
Pozdrowienia
BraZby
www.faq.accdb.pl
www.accdb.pl